$! **********************************************************************
$! * REBUILD_ALL_DISKS.COM						*
$! *									*
$! *	Performs a SET VOLUME/REBUILD on all disks, unless a single	*
$! *	target disk is specified as P1.					*
$! *									*
$! *	This software has been released into public domain. This	*
$! *	software may be freely copied, distributed, and modified so	*
$! *	long as it contains this message. This software is provided	*
$! *	as is, free of charge. The author assumes no responsibility	*
$! *	or liability for the use of this software.			*
$! *									*
$! *	Richware	http://richj.home.mindspring.com/Richware	*
$! *									*
$! *	9-DEC-1996	RDJ	Command Procedure Creation.		*
$! **********************************************************************
$!
$!
$   Set NoVerify
$   Set NoOn
$   Set Process/Priv=ALL
$   If P1 .NES. ""
$     Then
$       Call Rebuild_Disk 'P1'
$     Else
$ Disk_Loop:
$       Disk_Name = F$Device("*","Disk")
$       If Disk_Name .EQS. "" Then Goto No_More_Disks
$       If .NOT. F$GetDvi(Disk_Name,"AVL") Then Goto Disk_Loop
$       If .NOT. F$GetDvi(Disk_Name,"MNT") Then Goto Disk_Loop
$       If F$GetDvi(Disk_Name,"SHDW_MEMBER") Then Goto Disk_Loop
$       Call Rebuild_Disk 'Disk_Name'
$       Goto Disk_Loop
$ No_More_Disks:
$     EndIf
$   Exit
$!
$!
$! **********************************************************************
$! * Rebuild_Disk: Rebuild a Single Disk.				*
$! *	P1 = Disk Name							*
$! **********************************************************************
$ Rebuild_Disk: SubRoutine
$   Write SYS$OUTPUT "*************************************************"
$   Write SYS$OUTPUT " Disk: ''P1'"
$   Write SYS$OUTPUT ""
$   Set Volume/Rebuild 'P1'
$   Exit
$ EndSubRoutine	! Rebuild_Disk